5. tiempo

Manual básico de PRAAT
ANÁLISIS TEMPORAL
1
5. ANÁLISIS TEMPORAL
Obtener valores de duración en forma manual es muy sencillo. Basta con marcar el segmento en
la ventana de edición y la duración aparece en la ventana. Se puede escuchar la sección marcada
y observar la duración expresada en segundos.
Obtener valores en forma permanente y automatizada implica necesariamente hacer el
TextGrid de la señal de audio y etiquetar los segmentos que quieres medir (por ejemplo, con
etiquetas para cada sílaba).
Para conseguir las etiquetas y las duraciones basta con tener en el panel de objetos el
TextGrid. A partir de este momento, el objeto con la señal es irrelevante, pues la indicación
temporal está contenida en el TextGrid.
Seleccionado el objeto TextGrid, puedes usar el botón QUERY para obtener los datos.
Especialmente interesantes son las siguientes opciones de este menú:
GET
NUMBER OF INTERVALS…
con esta opción se despliega un formulario que pide el
número del estrato y da como resultado el número de intervalos que hay en ese estrato. Si no
hemos puesto marca alguna, entonces contará un intervalo.
GET
STARTING POINT…
al seleccionar esta opción aparece un formulario que pide el
número del estrato y el número del intervalo; da como resultado el tiempo de inicio de ese
intervalo.
GET
END POINT…
operación similar a la anterior que da como resultado la ubicación
temporal del punto final de ese intervalo.
GET LABEL OF INTERVAL… el formulario pide el número del estrato y el del intervalo; da
Manual básico de PRAAT
ANÁLISIS TEMPORAL
2
como resultado la etiqueta que contiene.
Una serie de opciones paralelas para los estratos de puntos da como resultado el número
de puntos de un estrato (GET NUMBER OF POINTS…), el tiempo en el que se ubica una marca (GET
TIME OF POINT…)
y la etiqueta (GET LABEL OF POINT…).
Con estas herramientas podemos obtener los valores de la duración de segmentos
etiquetados previamente, si le restamos al tiempo final de un intervalo, el tiempo de inicio. Para
lograrlo habrá que seleccionar el objeto TextGrid y usar el comando QUERY para conseguir la
primera etiqueta de un estrato, el punto de término y el punto de inicio de ese mismo intervalo.
Conseguidos esos elementos, deberás hacer la resta correspondiente (tiempo de término - tiempo
de inicio) y obtendrás la duración del segmento.
Esta es una manera correcta de hacerlo en PRAAT, pero resultará largo y tedioso. Sabemos
que los ordenadores son máquinas útiles especialmente para aquellas acciones que se repiten
muchas veces. Veremos ahora cómo programar una subrutina que realice estas tareas, ya que
efectivamente PRAAT lo permite y es una de las extraordinarias cualidades señaladas al inicio de
este manual. Las subrutinas se denominan scripts.
En concreto, la subrutina tendrá que hacer lo siguiente:
1. Seleccionar el TextGrid.
2. Seleccionar el estrato que corresponda.
3. En ese estrato, contar el número de intervalos y usar ese resultado como una
variable para lo que viene a continuación.
4. Para cada intervalo, obtener la etiqueta, los puntos de inicio y de término.
5. La subrutina deberá restar al valor del punto de término el valor del punto de
inicio y a ese resultado asignarle el nombre de una variable que identifique la
duración del segmento.
6. El paso final de esta tarea consiste en enviar a la pantalla las etiquetas y las
duraciones de los segmentos.
Manual básico de PRAAT
ANÁLISIS TEMPORAL
3
El script que realiza esa tarea, lo hace en los siguientes pasos:
1. Presenta un formulario para identificar el estrato (por defecto, 1) en el que se
quiere hacer las mediciones.
2. Limpia la pantalla de texto para volcar los resultados.
3. Escribe en la pantalla las expresiones “segmento” y “ms” separadas por una
tabulación.
4. Consigue el número de intervalos del estrato especificado en el formulario
inicial.
5. Un comando de tipo for hace que para todos los segmentos con etiquetas, se
identifique la etiqueta, el tiempo de inicio y el tiempo de término y se haga la
resta correspondiente y que finalmente envíe a la pantalla el valor de la
etiqueta y de la duración. Este comando contiene una condición: si un
segmento no tiene etiqueta, entonces no se envía el resultado a la pantalla.
Además, el resultado de la resta que expresa la duración del segmento es
multiplicado por 1000 para que el valor aparezca en milisegundos.
# Inicio
# 1. El formulario
form Mediciones de tiempo en un estrato
natural estrato 1
endform
# “estrato” es ahora nombre de una variable
# 2 Limpieza de la pantalla para el volcado de datos
clearinfo
# 3. Escribe en la pantalla “segmento” y “ms”
printline segmento'tab$'ms
# 4. Consigue el número de intervalos que hay en “estrato”
n = Get number of intervals... 'estrato'
# “n” es ahora nombre de una variable
# 5. El comando for que:
# consigue etiquetas y valores temporales
# hace la resta necesaria
# multiplica el resultado por 1000
# envía los resultados a la pantalla
Manual básico de PRAAT
ANÁLISIS TEMPORAL
4
for i to n
etiqueta$ = Get label of interval... 'estrato' i
if etiqueta$ != ""
t1 = Get starting point... 'estrato' i
t2 = Get end point... 'estrato' i
tt = t2-t1
tt = tt*1000
printline 'etiqueta$''tab$''tt:2'
endif
endfor
# “t1”, “t2” y “tt” son nombres de variables.
# fin del script
Texto de script 5.1. Medición de segmentos.
Para usar esta subrutina es necesario tener el TextGrid en el panel de objetos, abrir el
editor de scripts de PRAAT (PRAAT > NEW PRAAT SCRIPT), copiar o reescribir el texto del script
(las líneas precedidas por “#” no son necesarias) y ejecutar el script (RUN en el menú RUN del
menú del editor de scripts). El resultado debe ser un archivo de texto con dos columnas de datos.
Esos resultados los puedes llevar a una planilla electrónica.
Puedes guardar el script en un directorio especial para estas herramientas. En la pantalla
del editor de script, en el menú FILE, existe la opción para guardarlo. PRAAT permite incorporar
tus propios scripts en los menús del programa.
Otras mediciones
Hay unas mediciones de tiempo que son muy productivas en los análisis fonéticos y que
no son de segmentos exactamente, sino de relación entre dos puntos. El ejemplo más típico, pero
no el único, es el caso del VOT (voice onset time o ‘tiempo de inicio de la sonoridad’). Se usa
para describir consonantes oclusivas. Puedes ver interesantes descripciones y ejemplos en
Manual básico de PRAAT
ANÁLISIS TEMPORAL
5
Fernández Planas (2003: 97-98), Martínez Celdrán (2003: 80-84). Básicamente se mide el
tiempo que hay entre la explosión de una oclusiva y el inicio de la sonoridad. Si tomamos la
secuencia “ta”, observaremos un silencio que corresponde al período de oclusión de [ t ̪], luego
se observará la explosión y, después de un breve lapso, el inicio de la sonoridad de la vocal
siguiente. Lo mismo es válido para [ p ] y [ k ]. Para las oclusivas sordas, la sonoridad comienza
después de la explosión. En cambio si la secuencia es “da”, se observa que la sonoridad de [ d ̪],
y de las oclusivas sonoras en general, comienza antes de la explosión. La figura 5.1 muestra
ambos casos.
Figura 5.1. Secuencias “ta” y “da”. Las flechas señalan el momento del inicio de la
sonoridad. El tiempo entre líneas verticales corresponde a la duración del VOT.
Para medir el VOT, el procedimiento habitual es considerar la explosión como punto de
referencia y en función de él medir la distancia temporal al inicio de la sonoridad. Si la sonoridad
aparece después de la explosión (como en “ta”), se dice que el VOT es positivo. En cambio, si la
sonoridad comienza antes, el VOT será negativo.
Como en las mediciones de segmentos, esto se puede hacer manualmente seleccionando
la porción de tiempo que media entre la explosión y el inicio de la sonoridad en la ventana de
edición. También podemos usar el script ya expuesto, pero en estos casos no se podrá diferenciar
Manual básico de PRAAT
ANÁLISIS TEMPORAL
6
automáticamente entre valores negativos y positivos.
Para resolver este problema, se puede crear un script que funcione a partir de un TextGrid
con dos estratos puntuales y en cada uno poner una marca (la del primer estrato actuará como
referencia y se situará en el punto de la barra de explosión). Al poner las marcas en dos estratos
diferentes, garantizamos que el resultado puede ser positivo o negativo, ya que una actuará como
el cero (referencial) y la otra marca podrá situarse antes (valor negativo) o después (valor
positivo).
El script especificará el sonido que estamos estudiando mediante un formulario inicial.
Luego deberá trabajar con el TextGrid y obtener los valores temporales para las marcas que hay
en los dos estratos (no puede haber otras marcas) y restar del valor del estrato 2 el valor
considerado como referencia (el de la marca del estrato 1). Por supuesto, el script debe enviar los
resultados a la pantalla.
El siguiente script automatiza esa tarea:
# inicio del script
clearinfo
form Especificar sonido
word sonido
endform
archivo$ = selected$("TextGrid")
select TextGrid 'archivo$'
a = Get time of point... 1 1
b = Get time of point... 2 1
tiempo = b - a
printline 'sonido$''tab$''tiempo:3'
# fin del script
Texto de script 5.2. Medición de diferencia temporal entre dos puntos.
El resultado se presenta en segundos y con tres decimales, tal como indica el número “3”
después de los dos puntos “:” en la última línea de instrucción del script.